Brtdku

I'm creating a fish feeder with SG90 servo and NodeMCU

I used this sketch:

#include <ESP8266WiFi.h>

#include <PubSubClient.h>

#include <Servo.h>

// Update these with values suitable for your network.

const char* ssid = "your_wifi_hotspot";

const char* password = "your_wifi_password";

 const char* mqtt_server = "broker.mqttdashboard.com";

//const char* mqtt_server = "iot.eclipse.org";



Servo myservo;  // create servo object to control a servo

WiFiClient espClient;

PubSubClient client(espClient);



void setup_wifi() {

   delay(100);

  // We start by connecting to a WiFi network

    Serial.print("Connecting to ");

    Serial.println(ssid);

    WiFi.begin(ssid, password);

    while (WiFi.status() != WL_CONNECTED) 

    {

      delay(500);

      Serial.print(".");

    }

  randomSeed(micros());

  Serial.println("");

  Serial.println("WiFi connected");

  Serial.println("IP address: ");

  Serial.println(WiFi.localIP());

}



void callback(char* topic, byte* payload, unsigned int length) 

{

  Serial.print("Command from MQTT broker is : [");

  Serial.print(topic);

  for(int i=0;i<length;i++)

  {

    if((int)payload[i]>194||(int)payload[i]<0)

    break;

    myservo.write((int)payload[i]);              // tell servo to go to position in variable '(int)payload[i]'

  }

}//end callback



void reconnect() {

  // Loop until we're reconnected

  while (!client.connected()) 

  {

    Serial.print("Attempting MQTT connection...");

    // Create a random client ID

    String clientId = "ESP8266Client-";

    clientId += String(random(0xffff), HEX);

    // Attempt to connect

    //if you MQTT broker has clientID,username and password

    //please change following line to    if (client.connect(clientId,userName,passWord))

    if (client.connect(clientId.c_str()))

    {

      Serial.println("connected");

     //once connected to MQTT broker, subscribe command if any

      client.subscribe("OsoyooCommand");

    } else {

      Serial.print("failed, rc=");

      Serial.print(client.state());

      Serial.println(" try again in 5 seconds");

      // Wait 6 seconds before retrying

      delay(6000);

    }

  }

} //end reconnect()



void setup() {

  Serial.begin(115200);

  setup_wifi();

  client.setServer(mqtt_server, 1883);

  client.setCallback(callback);

  myservo.attach(D1);  // attaches the servo on pin D1 to the servo object

}



void loop() {

  if (!client.connected()) {

    reconnect();

  }

  client.loop();



}

The servo is working when I use MQTTBox in order to send a payload as "Decimal Array", it is however is giving me a hard time when I send payload as JSON string.

If I send "Decimal Array" 1 it does turn Servo to position 1, however if I simply send 1 as a payload as a string it moves Servo to position 49.
If I send payload as 2 it moves to position 50.
If I send payload as 10 then position is 4948
looks like position of 1 and position of 0 at the same time.

My ultimate goal is to send those payloads via HomeAssistant which are sent as string or JSON, however I don't find a correct solution at the moment.
I would highly appreciate any help or solution.

Looks like the motor is taking the position of the ASCII equivalent of the number when you send it as a string.

i.e.

• ASCII equivalent of the character '1' in 49 in decimal


• ASCII equivalent of the character '2' in 50 in decimal

Try sending the character 'a', the motor will go to 97.

If you want to send a string, you will have to change the following code:

for(int i=0;i<length;i++)

{

  if((int)payload[i]>194||(int)payload[i]<0)

    break;

  myservo.write((int)payload[i]);              // tell servo to go to position in variable '(int)payload[i]'

}

to:

int location=String((char*)payload).toInt()

if((location>194)||(location<0))

  return;

myservo.write(location);

MQTT payloads are UTF-8 encoded so the Arduino PubSubClient library treats the payload as an array of uint8_t.

If you want to send and receive JSON then you can use the ArduinoJson library to parse a JSON payload. So assuming a JSON payload like:

{

  "position": 123

}

Then you can implement a callback such as:

#include <ArduinoJson.h>



// Assuming a fixed sized JSON buffer

StaticJsonBuffer<200> jsonBuffer;



void callback(char* topic, byte* payload, unsigned int length) 

{

  JsonObject& root = jsonBuffer.parseObject(payload);



  if (root.success() && root.is<JsonObject>())

  {

    int position = root.as<JsonObject>().get<int>("position");



    myservo.write(position);

  }

}